cacalabs
/
libcaca
镜像自地址 https://github.com/cacalabs/libcaca.git
1
0
派生 0
代码 工单 0 版本发布 7 百科 动态
您最多选择25个主题 主题必须以字母或数字开头，可以包含连字符 (-)，并且长度不得超过35个字符
1955 提交
1 分支
37 MiB
 
 
 
 
 
 
目录树: 3ee1c297f2
分支列表 标签列表
${ item.name }
创建分支 ${ searchTerm }
从 '3ee1c297f2'
${ noResults }
libcaca/configure.ac

598 行
21 KiB
原始文件 Blame 文件历史 

  1. 

  2. AC_INIT([libcaca],[0.99.beta20])

  3. AC_PREREQ([2.69])

  4. AC_CONFIG_AUX_DIR(.auto)

  5. AC_CONFIG_MACRO_DIR(.auto)

  6. AC_CANONICAL_TARGET

  7. AM_INIT_AUTOMAKE([no-define tar-ustar silent-rules subdir-objects])

  8. dnl AM_MAINTAINER_MODE

  9. AM_DEFAULT_VERBOSITY=0

  10. 

  11. AM_CONFIG_HEADER(config.h)

  12. 

  13. LT_MAJOR="0"

  14. LT_MINOR="99"

  15. LT_MICRO="20"

  16. AC_SUBST(LT_MAJOR)

  17. AC_SUBST(LT_MINOR)

  18. AC_SUBST(LT_MICRO)

  19. LT_VERSION="$LT_MAJOR:$LT_MINOR:$LT_MICRO"

  20. AC_SUBST(LT_VERSION)

  21. 

  22. AM_PROG_CC_C_O

  23. AC_PROG_CPP

  24. AC_PROG_CXX

  25. AC_PROG_CXXCPP

  26. _AM_DEPENDENCIES([OBJC])

  27. OBJC="${CC}"

  28. AC_SUBST(OBJC)

  29. AC_SUBST(OBJCFLAGS)

  30. AM_PROG_AS

  31. 

  32. AC_LIBTOOL_WIN32_DLL

  33. AM_PROG_LIBTOOL

  34. AC_LIBTOOL_CXX

  35. 

  36. AC_C_CONST

  37. AC_C_INLINE

  38. AC_DIAGNOSE([obsolete],[your code may safely assume C89 semantics that RETSIGTYPE is void.

  39. Remove this warning and the `AC_CACHE_CHECK' when you adjust the code.])dnl

  40. AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(

  41. [AC_LANG_PROGRAM([#include <sys/types.h>

  42. #include <signal.h>

  43. ],

  44. 		 [return *(signal (0, 0)) (0) == 1;])],

  45. 		   [ac_cv_type_signal=int],

  46. 		   [ac_cv_type_signal=void])])

  47. AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers

  48. 		    (`int' or `void').])

  49. 

  50. 

  51. dnl  AC_PROG_EGREP only exists in autoconf 2.54+, so we use AC_EGREP_CPP right

  52. dnl  now otherwise it might be set in an obscure if statement. Same thing for

  53. dnl  PKG_PROG_PKG_CONFIG which needs to be called first.

  54. AC_EGREP_CPP(yes, foo)

  55. PKG_PROG_PKG_CONFIG()

  56. m4_pattern_allow([^PKG_CONFIG_LIBDIR$])

  57. if test "${build}" != "${host}" -a "${PKG_CONFIG_LIBDIR}" = ""; then

  58.   export PKG_CONFIG_LIBDIR=/dev/null

  59. fi

  60. 

  61. AC_MSG_CHECKING(for suffix of libraries)

  62. case "$shrext_cmds" in

  63.   .dll) eval LT_SUFFIX="-$LT_MAJOR$shrext_cmds" ;;

  64.   "") LT_SUFFIX=".so.$LT_MAJOR" ;;

  65.   *) eval LT_SUFFIX="$shrext_cmds.$LT_MAJOR" ;;

  66. esac

  67. AC_MSG_RESULT($LT_SUFFIX)

  68. AC_SUBST(LT_SUFFIX)

  69. 

  70. dnl  global configuration features

  71. AC_ARG_ENABLE(kernel,

  72.   [  --enable-kernel         kernel mode (default no)])

  73. 

  74. dnl  output driver features

  75. AC_ARG_ENABLE(slang,

  76.   [  --enable-slang          slang graphics support (autodetected)])

  77. AC_ARG_ENABLE(ncurses,

  78.   [  --enable-ncurses        ncurses graphics support (autodetected)])

  79. AC_ARG_ENABLE(win32,

  80.   [  --enable-win32          Windows console support (autodetected)])

  81. AC_ARG_ENABLE(conio,

  82.   [  --enable-conio          DOS conio.h graphics support (autodetected)])

  83. AC_ARG_ENABLE(x11,

  84.   [  --enable-x11            X11 support (autodetected)])

  85. AC_ARG_ENABLE(gl,

  86.   [  --enable-gl             OpenGL support (autodetected)])

  87. AC_ARG_ENABLE(cocoa,

  88.   [  --enable-cocoa          Cocoa support (autodetected)])

  89. AC_ARG_ENABLE(network,

  90.   [  --enable-network        network support (autodetected)])

  91. AC_ARG_ENABLE(vga,

  92.   [  --enable-vga            VGA support for kernel mode (autodetected)])

  93. 

  94. dnl  language bindings

  95. AC_ARG_ENABLE(csharp,

  96.   [  --enable-csharp         C# bindings (autodetected)])

  97. AC_ARG_ENABLE(java,

  98.   [  --enable-java           Java bindings (autodetected)])

  99. AC_ARG_ENABLE(cxx,

  100.   [  --enable-cxx            C++ bindings (autodetected)])

  101. AC_ARG_ENABLE(python,

  102.   [  --enable-python         Python bindings (autodetected)])

  103. AC_ARG_ENABLE(ruby,

  104.   [  --enable-ruby           Ruby bindings (autodetected)])

  105. 

  106. dnl  example programs features

  107. AC_ARG_ENABLE(imlib2,

  108.   [  --enable-imlib2         Imlib2 graphics support (autodetected)])

  109. 

  110. dnl  conditional builds

  111. AC_ARG_ENABLE(debug,

  112.   [  --enable-debug          build debug versions of the library (default no)])

  113. AC_ARG_ENABLE(profiling,

  114.   [  --enable-profiling      activate built-in profiling (default no)])

  115. AC_ARG_ENABLE(plugins,

  116.   [  --enable-plugins        make X11 and GL drivers plugins (default disabled)])

  117. AC_ARG_ENABLE(doc,

  118.   [  --enable-doc            build documentation (needs doxygen and LaTeX)])

  119. AC_ARG_ENABLE(cppunit,

  120.   [  --enable-cppunit        use cppunit for unit tests (autodetected)])

  121. AC_ARG_ENABLE(zzuf,

  122.   [  --enable-zzuf           use zzuf for fuzzing tests (autodetected)])

  123. 

  124. ac_cv_my_have_kernel="no"

  125. if test "${enable_kernel}" = "yes"; then

  126.   ac_cv_my_have_kernel="yes"

  127.   CPPFLAGS="${CPPFLAGS} -I. -D__KERNEL__ -nostdinc -include kernel/klibc.h -fno-stack-protector"

  128.   CCASFLAGS="${CCASFLAGS} -I. -fno-stack-protector"

  129.   CFLAGS="${CFLAGS} -fno-builtin -O0 -I. -I.. -I../caca/ -Wall -D__KERNEL__ -fno-stack-protector -m32"

  130.   LDFLAGS="${LDFLAGS} -nostdlib -Wl,-N -Wl,-Ttext -Wl,100000 -fno-stack-protector"

  131.   AC_DEFINE(USE_KERNEL, 1, Define to 1 to activate kernel mode)

  132. fi

  133. AM_CONDITIONAL(USE_KERNEL, test "${ac_cv_my_have_kernel}" = "yes")

  134. 

  135. AC_CHECK_HEADERS(stdio.h stdarg.h signal.h sys/ioctl.h sys/time.h endian.h unistd.h arpa/inet.h netinet/in.h winsock2.h errno.h locale.h getopt.h dlfcn.h termios.h)

  136. AC_CHECK_FUNCS(signal ioctl snprintf sprintf_s vsnprintf vsnprintf_s getenv putenv strcasecmp htons)

  137. AC_CHECK_FUNCS(usleep gettimeofday atexit)

  138. 

  139. AC_CHECK_HEADERS(_mingw.h,

  140.  [CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=0"])

  141. 

  142. ac_cv_have_getopt_long="no"

  143. AC_CHECK_FUNCS(getopt_long,

  144.  [ac_cv_have_getopt_long="yes"],

  145.  [AC_CHECK_LIB(gnugetopt, getopt_long,

  146.    [ac_cv_have_getopt_long="yes"

  147.     GETOPT_LIBS="${GETOPT_LIBS} -lgnugetopt"])])

  148. if test "$ac_cv_have_getopt_long" != "no"; then

  149.   AC_DEFINE(HAVE_GETOPT_LONG, 1, Define to 1 if you have the ‘getopt_long’ function.)

  150. fi

  151. AC_SUBST(GETOPT_LIBS)

  152. 

  153. AC_MSG_CHECKING(for Sleep)

  154. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <windows.h>]], [[Sleep(42);]])],[AC_MSG_RESULT(yes)

  155.   AC_DEFINE(HAVE_SLEEP, 1, [Define to 1 if you have the ‘Sleep’ function.])],[AC_MSG_RESULT(no)])

  156. 

  157. AC_MSG_CHECKING(for fsin/fcos)

  158. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[double x; asm volatile("fsin; fcos":"=t"(x):);]])],[AC_MSG_RESULT(yes)

  159.   AC_DEFINE(HAVE_FSIN_FCOS, 1, [Define to 1 if you have the ‘fsin’ and ‘fcos’ instructions.])],[AC_MSG_RESULT(no)])

  160. 

  161. AC_MSG_CHECKING(for fldln2/fxch/fyl2x)

  162. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[double x; asm volatile("fldln2; fldln2; fxch; fyl2x":"=t"(x):);]])],[AC_MSG_RESULT(yes)

  163.   AC_DEFINE(HAVE_FLDLN2, 1, [Define to 1 if you have the ‘fldln2’ and other floating point instructions.])],[AC_MSG_RESULT(no)])

  164. 

  165. AC_CHECK_HEADERS(zlib.h)

  166. AC_CHECK_LIB(z, gzopen, [ZLIB_LIBS="${ZLIB_LIBS} -lz"])

  167. 

  168. AC_CHECK_LIB(m, sin, MATH_LIBS="${MATH_LIBS} -lm")

  169. 

  170. CACA_DRIVERS=""

  171. 

  172. if test "${enable_conio}" != "no"; then

  173.   ac_cv_my_have_conio="no"

  174.   AC_CHECK_HEADERS(conio.h,

  175.    [AC_MSG_CHECKING(for ScreenUpdate in pc.h)

  176.     AC_EGREP_HEADER(ScreenUpdate, pc.h,

  177.      [ac_cv_my_have_conio="yes"

  178.       AC_MSG_RESULT(yes)

  179.       AC_DEFINE(SCREENUPDATE_IN_PC_H, 1,

  180.                 Define to 1 if <pc.h> defines ScreenUpdate.)

  181.       AC_DEFINE(USE_CONIO, 1, Define to 1 to activate the conio.h backend driver)

  182.       CACA_DRIVERS="${CACA_DRIVERS} conio"],

  183.      [AC_MSG_RESULT(no)])])

  184.   if test "${ac_cv_my_have_conio}" = "no" -a "${enable_conio}" = "yes"; then

  185.     AC_MSG_ERROR([cannot find conio.h])

  186.   fi

  187. fi

  188. 

  189. if test "${enable_win32}" != "no"; then

  190.   ac_cv_my_have_win32="no"

  191.   AC_CHECK_HEADERS(windows.h,

  192.    [AC_MSG_CHECKING(for AllocConsole in windows.h)

  193.     AC_EGREP_HEADER(AllocConsole, windows.h,

  194.      [ac_cv_my_have_win32="yes"

  195.       AC_MSG_RESULT(yes)

  196.       AC_DEFINE(ALLOCCONSOLE_IN_WINDOWS_H, 1,

  197.                 Define to 1 if <windows.h> defines AllocConsole.)

  198.       AC_DEFINE(USE_WIN32, 1, Define to 1 to activate the win32 backend driver)

  199.       CACA_DRIVERS="${CACA_DRIVERS} win32"],

  200.      [AC_MSG_RESULT(no)])])

  201.   if test "${ac_cv_my_have_win32}" = "no" -a "${enable_win32}" = "yes"; then

  202.     AC_MSG_ERROR([cannot find win32 console development files])

  203.   fi

  204. fi

  205. 

  206. if test "${enable_slang}" != "no"; then

  207.   ac_cv_my_have_slang="no"

  208.   AC_CHECK_HEADERS(slang.h slang/slang.h,

  209.    [ac_cv_my_have_slang="yes"

  210.     AC_DEFINE(USE_SLANG, 1, Define to 1 to activate the slang backend driver)

  211.     AC_CHECK_LIB(slang, SLsmg_utf8_enable,

  212.      [AC_DEFINE(HAVE_SLSMG_UTF8_ENABLE, 1, Define to 1 if you have the ‘SLsmg_utf8_enable’ function.)])

  213.     CPPFLAGS="${CPPFLAGS} -DOPTIMISE_SLANG_PALETTE=1"

  214.     CACA_LIBS="${CACA_LIBS} -lslang"

  215.     CACA_DRIVERS="${CACA_DRIVERS} slang"

  216.     break])

  217.   if test "${ac_cv_my_have_slang}" = "no" -a "${enable_slang}" = "yes"; then

  218.     AC_MSG_ERROR([cannot find slang development files])

  219.   fi

  220. fi

  221. 

  222. if test "${enable_x11}" != "no"; then

  223.   AC_PATH_X

  224.   AC_CHECK_LIB(X11, XOpenDisplay,

  225.    [ac_cv_my_have_x11="yes"

  226.     if test -n "${x_includes}"; then X_CFLAGS="-I${x_includes}"; fi

  227.     if test -n "${x_libraries}"; then X_LIBS="-L${x_libraries}"; fi

  228.     AC_DEFINE(USE_X11, 1, Define to 1 to activate the X11 backend driver)

  229.     CPPFLAGS="${CPPFLAGS} ${X_CFLAGS}"

  230.     X11_LIBS="${X11_LIBS} -lX11 ${X_LIBS}"

  231.     CACA_DRIVERS="${CACA_DRIVERS} x11"],

  232.    [ac_cv_my_have_x11="no"],

  233.    [[`if test -n "${x_libraries}"; then echo -L${x_libraries}; fi`]])

  234.   AC_CHECK_HEADERS(X11/XKBlib.h)

  235.   if test "${ac_cv_my_have_x11}" != "yes" -a "${enable_x11}" = "yes"; then

  236.     AC_MSG_ERROR([cannot find X11 development files])

  237.   fi

  238. fi

  239. 

  240. if test "${enable_gl}" != "no"; then

  241.   ac_cv_my_have_gl="no"

  242.   AC_CHECK_HEADERS(GL/gl.h OpenGL/gl.h,

  243.    [AC_CHECK_HEADERS(GL/glut.h,

  244.      [AC_CHECK_LIB(glut, glutCloseFunc,

  245.        [AC_DEFINE(HAVE_GLUTCLOSEFUNC, 1, Define to 1 if you have the ‘glutCloseFunc’ function.)])

  246.       AC_CHECK_LIB(glut, glutMainLoopEvent,

  247.        [ac_cv_my_have_gl="yes"])

  248.       AC_CHECK_LIB(glut, glutCheckLoop,

  249.        [ac_cv_my_have_gl="yes"

  250.         AC_DEFINE(HAVE_GLUTCHECKLOOP, 1, Define to 1 if you have the ‘glutCheckLoop’ function.)])])

  251.       break])

  252.   if test "${ac_cv_my_have_gl}" = "yes"; then

  253.     AC_DEFINE(USE_GL, 1, Define to 1 to activate the OpenGL backend driver)

  254.     GL_LIBS="${GL_LIBS} -lGL -lGLU -lglut"

  255.     CACA_DRIVERS="${CACA_DRIVERS} gl"

  256.   elif test "${enable_gl}" = "yes"; then

  257.     AC_MSG_ERROR([cannot find OpenGL+FreeGLUT development files])

  258.   fi

  259.   PKG_CHECK_MODULES(FTGL, ftgl >= 2.1.3, [FTGL="yes"], [FTGL="no"])

  260. fi

  261. AM_CONDITIONAL(USE_FTGL, test "${FTGL}" = "yes")

  262. 

  263. if test "${enable_cocoa}" != "no"; then

  264.   ac_cv_my_have_cocoa="no"

  265.   save_CFLAGS="$CFLAGS"

  266.   CFLAGS="$CFLAGS -ObjC++"

  267.   AC_CHECK_HEADERS(Cocoa/Cocoa.h,

  268.    [ac_cv_my_have_cocoa="yes"])

  269.   CFLAGS="$save_CFLAGS"

  270.   if test "${ac_cv_my_have_cocoa}" = "yes"; then

  271.     [[[ "$target_os" =~ [0-9]+ ]]] && darwin_ver="${BASH_REMATCH[[0]]}"

  272.     case x${target} in

  273.     xpowerpc*darwin*)

  274.       # 10.3 needed to link with X11

  275.       MACOSX_SDK="${MACOSX_SDK:-/Developer/SDKs/MacOSX10.3.9.sdk}"

  276.       GCC_VERSION="${GCC_VERSION:-3.3}"

  277.       ARCH="${ARCH:--arch ppc}"

  278.       MACOSX_SDK_CFLAGS="${MACOSX_SDK_CFLAGS:--nostdinc -isystem ${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION} -isystem ${MACOSX_SDK}/usr/include}"

  279.       MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CXXFLAGS:--nostdinc++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++ -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/ppc-darwin -I${MACOSX_SDK}/usr/include/gcc/darwin/${GCC_VERSION}/c++/backward}"

  280.       MACOSX_SDK_LDFLAGS="${MACOSX_SDK_LDFLAGS:--L${MACOSX_SDK}/usr/lib/gcc/darwin -L${MACOSX_SDK}/usr/lib/gcc/darwin/${GCC_VERSION} -L${MACOSX_SDK}/usr/lib}"

  281.       ;;

  282.     x*86_64*darwin*)

  283.       MACOSX_SDK="${MACOSX_SDK:-/Developer/SDKs/MacOSX10.5.sdk}"

  284.       GCC_VERSION="${GCC_VERSION:-4.0}"

  285.       ARCH="${ARCH:--arch x86_64}"

  286.       MACOSX_SDK_CFLAGS="${MACOSX_SDK_CFLAGS:--isysroot ${MACOSX_SDK}}"

  287.       MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CXXFLAGS:-${MACOSX_SDK_CFLAGS}}"

  288.       ;;

  289.     x*86*darwin*)

  290.       MACOSX_SDK="${MACOSX_SDK:-/Developer/SDKs/MacOSX10.6.sdk}"

  291.       GCC_VERSION="${GCC_VERSION:-4.0}"

  292.       ARCH="${ARCH:--arch x86_64}"

  293.       MACOSX_SDK_CFLAGS="${MACOSX_SDK_CFLAGS:--isysroot ${MACOSX_SDK}}"

  294.       MACOSX_SDK_CXXFLAGS="${MACOSX_SDK_CXXFLAGS:-${MACOSX_SDK_CFLAGS}}"

  295.       ;;

  296.     esac

  297.     CC="${CC:-gcc-${GCC_VERSION}}"

  298.     CXX="${CXX:-g++-${GCC_VERSION}}"

  299.     if [[ "$darwin_ver" -lt "13" ]]; then

  300.       MACOSX_SDK_FRAMEWORKS="${MACOSX_SDK_FRAMEWORKS:--F${MACOSX_SDK}/System/Library/Frameworks}"

  301.       CPPFLAGS="${CPPFLAGS} ${ARCH} ${MACOSX_SDK_FRAMEWORKS}"

  302.       CFLAGS="${CFLAGS} ${MACOSX_SDK_CFLAGS} -mmacosx-version-min=10.5"

  303.       CXXFLAGS="${CXXFLAGS} ${MACOSX_SDK_CXXFLAGS} -mmacosx-version-min=10.5"

  304.       OBJCFLAGS="${OBJCFLAGS} ${MACOSX_SDK_CFLAGS} -mmacosx-version-min=10.5"

  305.       LDFLAGS="${ARCH} ${MACOSX_SDK_LDFLAGS} ${LDFLAGS}"

  306.       CACA_LIBS="${CACA_LIBS} -Wl,-syslibroot,${MACOSX_SDK},-framework,Cocoa"

  307.     else

  308.       CACA_LIBS="${CACA_LIBS} -Wl,-framework,Cocoa"

  309.     fi

  310.     CACA_DRIVERS="${CACA_DRIVERS} cocoa"

  311.     AC_DEFINE(USE_COCOA, 1, Define to 1 to activate the Cocoa backend driver)

  312.   elif test "${enable_cocoa}" = "yes"; then

  313.     AC_MSG_ERROR([cannot find Cocoa development files])

  314.   fi

  315. fi

  316. AM_CONDITIONAL(USE_COCOA, test "${ac_cv_my_have_cocoa}" = "yes")

  317. 

  318. if test "${enable_ncurses}" != "no"; then

  319.   ac_cv_my_have_ncurses="no"

  320.   AC_CHECK_HEADERS(ncursesw/ncurses.h ncurses/ncurses.h ncurses.h curses.h,

  321.    [ncurses="no"

  322.     AC_CHECK_LIB(ncursesw, initscr,

  323.      [ncurses="-lncursesw"],

  324.      [AC_CHECK_LIB(ncurses, initscr,

  325.        [ncurses="-lncurses"])])

  326.     if test "${ncurses}" = "no"; then

  327.       continue

  328.     fi

  329.     ac_cv_my_have_ncurses="yes"

  330.     AC_DEFINE(USE_NCURSES, 1, Define to 1 to activate the ncurses backend driver)

  331.     CACA_LIBS="${CACA_LIBS} ${ncurses}"

  332.     CACA_DRIVERS="${CACA_DRIVERS} ncurses"

  333.     dnl  Check for resizeterm or resize_term

  334.     SAVED_LIBS="${LIBS}"

  335.     LIBS="${LIBS} ${ncurses}"

  336.     AC_CHECK_FUNCS(resizeterm resize_term)

  337.     LIBS="${SAVED_LIBS}"

  338.     break])

  339.   if test "${ac_cv_my_have_ncurses}" = "no" -a "${enable_ncurses}" = "yes"; then

  340.     AC_MSG_ERROR([cannot find ncurses development files])

  341.   fi

  342. fi

  343. 

  344. if test "${enable_vga}" != "no"; then

  345.   if test "${ac_cv_my_have_kernel}" = "yes"; then

  346.     AC_DEFINE(USE_VGA, 1, Define to 1 to activate the VGA backend driver)

  347.     CACA_DRIVERS="${CACA_DRIVERS} vga"

  348.   elif test "${enable_vga}" = "yes"; then

  349.     AC_MSG_ERROR([--enable-vga requires --enable-kernel])

  350.   fi

  351. fi

  352. 

  353. if test "${enable_debug}" = "yes"; then

  354.   AC_DEFINE(DEBUG, 1, Define to 1 to activate debug)

  355. fi

  356. 

  357. if test "${enable_profiling}" = "yes"; then

  358.   AC_DEFINE(PROF, 1, Define to 1 to activate profiling)

  359. fi

  360. 

  361. if test "${enable_plugins}" = "yes"; then

  362.   ac_cv_my_have_plugins="yes"

  363.   AC_DEFINE(USE_PLUGINS, 1, Define to 1 to activate plugins)

  364.   CACA_LIBS="${CACA_LIBS} -ldl"

  365. else

  366.   CACA_CFLAGS="${CACA_CFLAGS} ${X11_CFLAGS} ${GL_CFLAGS} ${FTGL_CFLAGS}"

  367.   CACA_LIBS="${CACA_LIBS} ${X11_LIBS} ${GL_LIBS} ${FTGL_LIBS}"

  368. fi

  369. AM_CONDITIONAL(USE_PLUGINS, test "${ac_cv_my_have_plugins}" = "yes")

  370. 

  371. AC_MSG_CHECKING(valid output drivers)

  372. if test -z "${CACA_DRIVERS}"; then

  373.   AC_MSG_RESULT(no)

  374.   AC_MSG_WARN([no output drivers were selected!])

  375. else

  376.   CACA_DRIVERS="${CACA_DRIVERS# *}"

  377.   AC_MSG_RESULT([${CACA_DRIVERS}])

  378. fi

  379. 

  380. AC_SUBST(MATH_LIBS)

  381. AC_SUBST(ZLIB_LIBS)

  382. AC_SUBST(GETOPT_LIBS)

  383. AC_SUBST(CACA_CFLAGS)

  384. AC_SUBST(CACA_LIBS)

  385. AC_SUBST(X11_CFLAGS)

  386. AC_SUBST(X11_LIBS)

  387. AC_SUBST(GL_CFLAGS)

  388. AC_SUBST(GL_LIBS)

  389. 

  390. # Optimizations

  391. CFLAGS="${CFLAGS} -g -O2 -fno-strength-reduce -fomit-frame-pointer"

  392. # Code qui fait des warnings == code de porc == deux baffes dans ta gueule

  393. CFLAGS="${CFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wstrict-prototypes -Wshadow -Waggregate-return -Wmissing-prototypes -Wnested-externs -Wsign-compare"

  394. CXXFLAGS="${CXXFLAGS} -Wall -Wpointer-arith -Wcast-align -Wcast-qual -Wshadow -Wsign-compare"

  395. 

  396. CACA_BINDINGS=""

  397. 

  398. # Build the C++ bindings?

  399. ac_cv_my_have_cxx="no"

  400. if test "${enable_cxx}" != "no"; then

  401.   AC_MSG_CHECKING([working <iostream>])

  402.   AC_LANG_PUSH(C++)

  403.   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <iostream>]], [[]])],[ac_cv_my_have_cxx="yes"

  404.     CACA_BINDINGS="${CACA_BINDINGS} C++"],[])

  405.   AC_LANG_POP(C++)

  406.   AC_MSG_RESULT([$ac_cv_my_have_cxx])

  407. fi

  408. AM_CONDITIONAL(USE_CXX, test "${ac_cv_my_have_cxx}" = "yes")

  409. 

  410. # Build the .NET bindings?

  411. ac_cv_my_have_csharp="no"

  412. if test "${enable_csharp}" != "no"; then

  413.   AC_PATH_PROG(CSC, csc, no)

  414.   if test "$CSC" = "no"; then

  415.     AC_PATH_PROG(GMCS, gmcs, no)

  416.     CSC="$GMCS"

  417.   fi

  418.   AC_PATH_PROG(GACUTIL, gacutil, no)

  419.   if test "${CSC}" != "no" -a "${GACUTIL}" != "no"; then

  420.     ac_cv_my_have_csharp="yes"

  421.     CACA_BINDINGS="${CACA_BINDINGS} C#"

  422.   fi

  423. fi

  424. AM_CONDITIONAL(USE_CSHARP, test "${ac_cv_my_have_csharp}" = "yes")

  425. 

  426. # Build the Java bindings?

  427. ac_cv_my_have_java="no"

  428. if test "${enable_java}" != "no" -a "${ac_cv_my_have_kernel}" != "yes"; then

  429.   AC_PATH_PROG(JAVAC, javac, no)

  430.   AC_PATH_PROG(JAVAH, javah, no)

  431.   AC_PATH_PROG(JAR, jar, no)

  432.   if test "${JAVAC}" != "no" -a "${JAVAH}" != "no" -a "${JAR}" != "no"; then

  433.     if test "$JAVA_HOME" = ""; then

  434.       # Try to resolve JAVA_HOME

  435.       JAVAC_EXE="$JAVAC"

  436.       # Follow symlinks

  437.       while test -h "$JAVAC_EXE"; do

  438.         ls=`ls -ld "$JAVAC_EXE"`

  439.         link=`expr "$ls" : '.*-> \(.*\)$'`

  440.         if expr "$link" : '/.*' > /dev/null; then

  441.           JAVAC_EXE="$link"

  442.         else

  443.           JAVAC_EXE="`dirname "$JAVAC_EXE"`/$link"

  444.         fi

  445.       done

  446.       JAVA_HOME="`dirname $JAVAC_EXE`/.."

  447.     fi

  448.     # Include path to jni.h

  449.     JAVA_CFLAGS="${JAVA_CFLAGS} -I$JAVA_HOME/include"

  450.     # Add the OS specific include path

  451.     for dir in $JAVA_HOME/include/*; do

  452.       if test -f "$dir/jni_md.h"; then

  453.         JAVA_CFLAGS="${JAVA_CFLAGS} -I$dir"

  454.       fi

  455.     done

  456.     AC_SUBST(JAVA_CFLAGS)

  457.     AC_SUBST(JAVA_LIBS)

  458.     AC_LANG_PUSH(C)

  459.     CPPFLAGS="${CPPFLAGS} ${JAVA_CFLAGS}"

  460.     AC_CHECK_HEADERS([jni.h],

  461.      [ac_cv_my_have_java="yes"

  462.       CACA_BINDINGS="${CACA_BINDINGS} Java"])

  463.     AC_LANG_POP(C)

  464.   fi

  465. fi

  466. AM_CONDITIONAL(USE_JAVA, test "${ac_cv_my_have_java}" = "yes")

  467. 

  468. # Build the Python bindings?

  469. ac_cv_my_have_python="no"

  470. if test "${enable_python}" != "no"; then

  471.   AM_PATH_PYTHON(2.2, ac_cv_my_have_python="yes", :)

  472. fi

  473. AM_CONDITIONAL(USE_PYTHON, test "${ac_cv_my_have_python}" = "yes")

  474. 

  475. # Build the Ruby bindings?

  476. ac_cv_my_have_ruby="no"

  477. ac_cv_my_have_ruby_minitest="no"

  478. if test "${enable_ruby}" != "no"; then

  479.   AC_PATH_PROG(RUBY, ruby, no)

  480.   if test "${RUBY}" != "no"; then

  481.     RUBY_CFLAGS="$("${RUBY}" -r mkmf -e 'conf = RbConfig::CONFIG.merge("hdrdir" => $hdrdir, "arch_hdrdir" => $arch_hdrdir); print RbConfig::expand("#$INCFLAGS", conf)')"

  482.     RUBY_LIBS="-L$("${RUBY}" -r rbconfig -e 'print RbConfig::CONFIG@<:@"libdir"@:>@') -l$("${RUBY}" -r rbconfig -e 'print RbConfig::CONFIG@<:@"RUBY_SO_NAME"@:>@')"

  483.     RUBY_SITEARCHDIR=`"${RUBY}" -r rbconfig -e 'print RbConfig::CONFIG@<:@"sitearchdir"@:>@'`

  484.     RUBY_SITELIBDIR=`"${RUBY}" -r rbconfig -e 'print RbConfig::CONFIG@<:@"sitelibdir"@:>@'`

  485.     AC_SUBST(RUBY_CFLAGS)

  486.     AC_SUBST(RUBY_LIBS)

  487.     AC_SUBST(RUBY_SITEARCHDIR)

  488.     AC_SUBST(RUBY_SITELIBDIR)

  489.     CPPFLAGS="${CPPFLAGS} ${RUBY_CFLAGS}"

  490.     AC_CHECK_HEADERS([ruby.h],

  491.      [ac_cv_my_have_ruby="yes"

  492.       CACA_BINDINGS="${CACA_BINDINGS} Ruby"])

  493.     # For unit tests

  494.     AC_MSG_CHECKING(for ruby-minitest)

  495.     if "${RUBY}" -e "require 'minitest'" 2>/dev/null; then

  496.       ac_cv_my_have_ruby_minitest="yes"

  497.     fi

  498.     AC_MSG_RESULT(${ac_cv_my_have_ruby_minitest})

  499.   fi

  500. fi

  501. AM_CONDITIONAL(USE_RUBY, test "${ac_cv_my_have_ruby}" = "yes")

  502. AM_CONDITIONAL(USE_RUBY_MINITEST, test "${ac_cv_my_have_ruby_minitest}" = "yes")

  503. 

  504. AC_MSG_CHECKING(available language bindings)

  505. if test -z "${CACA_BINDINGS}"; then

  506.   AC_MSG_RESULT(no)

  507. else

  508.   CACA_BINDINGS="${CACA_BINDINGS# *}"

  509.   AC_MSG_RESULT([${CACA_BINDINGS}])

  510. fi

  511. 

  512. # Build cacaserver?

  513. ac_cv_my_have_network="no"

  514. AC_CHECK_HEADERS(sys/socket.h,

  515.  [ac_cv_my_have_network="yes"])

  516. AM_CONDITIONAL(USE_NETWORK, test "${ac_cv_my_have_network}" = "yes")

  517. 

  518. # Use Imlib2?

  519. if test "${enable_imlib2}" != "no"; then

  520.   PKG_CHECK_MODULES(IMLIB2, imlib2, [IMLIB2="yes"], [IMLIB2="no"])

  521.   if test "${IMLIB2}" = "yes"; then

  522.     AC_DEFINE(USE_IMLIB2, 1, Define to 1 to use Imlib2)

  523.   fi

  524. fi

  525. 

  526. # Build development tools?

  527. PKG_CHECK_MODULES(PANGOFT2, pangoft2, [PANGOFT2="yes"], [PANGOFT2="no"])

  528. AM_CONDITIONAL(USE_PANGO, test "${PANGOFT2}" = "yes")

  529. 

  530. # Build documentation?

  531. DOXYGEN="no"

  532. LATEX="no"

  533. if test "${enable_doc}" != "no"; then

  534.   AC_PATH_PROG(DOXYGEN, doxygen, no)

  535.   if test "${DOXYGEN}" != "no"; then

  536.     # Build LaTeX documentation?

  537.     AC_PATH_PROG(LATEX, pdflatex, no)

  538.     AC_PATH_PROG(KPSEWHICH, kpsewhich, no)

  539.     AC_PATH_PROG(DVIPS, dvips, no)

  540.     if test "${DVIPS}" = "no" -o "${KPSEWHICH}" = "no"; then

  541.       LATEX="no"

  542.     fi

  543.     if test "${LATEX}" != "no"; then

  544.       AC_MSG_CHECKING(for a4.sty and a4wide.sty)

  545.       if "${KPSEWHICH}" a4.sty >/dev/null 2>&1; then

  546.         if "${KPSEWHICH}" a4wide.sty >/dev/null 2>&1; then

  547.           AC_MSG_RESULT(yes)

  548.         else

  549.           LATEX="no"

  550.           AC_MSG_RESULT(no)

  551.         fi

  552.       else

  553.         LATEX="no"

  554.         AC_MSG_RESULT(no)

  555.       fi

  556.     fi

  557.   fi

  558. fi

  559. AM_CONDITIONAL(BUILD_DOCUMENTATION, test "${DOXYGEN}" != "no")

  560. AM_CONDITIONAL(USE_LATEX, test "${LATEX}" != "no")

  561. 

  562. # Use cppunit for unit tests?

  563. PKG_CHECK_MODULES(CPPUNIT, cppunit, [CPPUNIT="yes"], [CPPUNIT="no"])

  564. AM_CONDITIONAL(USE_CPPUNIT, test "$CPPUNIT" = "yes")

  565. 

  566. # Use zzuf for fuzzing tests?

  567. ZZUF="no"

  568. if test "${enable_zzuf}" != "no"; then

  569.   AC_PATH_PROG(ZZUF, zzuf, no)

  570. fi

  571. AM_CONDITIONAL(USE_ZZUF, test "${ZZUF}" != "no")

  572. 

  573. AC_CONFIG_FILES(

  574.  [Makefile

  575.   kernel/Makefile

  576.   caca/Makefile

  577.   caca/t/Makefile

  578.   src/Makefile

  579.   examples/Makefile

  580.   tools/Makefile

  581.   java/Makefile

  582.   caca-sharp/Makefile

  583.   cxx/Makefile

  584.   python/Makefile

  585.   ruby/Makefile

  586.   doc/Makefile

  587.   build/Makefile

  588. ])

  589. AC_CONFIG_FILES(

  590.  [caca/caca.pc

  591.   caca-sharp/caca-sharp.dll.config

  592.   cxx/caca++.pc

  593.   doc/doxygen.cfg

  594. ])

  595. AC_CONFIG_FILES([caca-config], [chmod 0755 caca-config])

  596. AC_OUTPUT